#include 'umfunc2.sqc'

!************************************************************************
! Get-XLAT-Value
!************************************************************************
Begin-Procedure Get-XLAT-Value($FieldName, :$FieldValue)

let $Valid_XLAT = 'N'

BEGIN-SELECT
PSXL.FIELDVALUE

	let $Valid_XLAT = 'Y'

FROM PSXLATITEM PSXL
WHERE PSXL.FIELDNAME   = $FieldName
AND 	PSXL.FIELDVALUE  = $FieldValue
AND 	PSXL.EFF_STATUS  = 'A'
AND 	PSXL.EFFDT = (SELECT MAX(PSXL1.EFFDT) FROM PSXLATITEM PSXL1
					WHERE PSXL.FIELDNAME = PSXL1.FIELDNAME
					AND PSXL.FIELDVALUE 	= PSXL1.FIELDVALUE
					AND PSXL1.EFFDT 	  <= SYSDATE)
END-SELECT

End-Procedure Get-XLAT-Value

!************************************************************************
! Procedure Get-Last-Word
!   Requires 2 input variables: $Search_String and $Search_For
!   Returns 1 variable:  $Last_Word
!************************************************************************
Begin-Procedure Get-Last-Word($Search_String, $Search_For, :$Last_Word)

		let #i = 1
		let #Word_Position = 0
		let #String_Length = length($Search_String)

		while #Word_Position = 0
			let #Word_Position = instr($Search_String,$Search_For,#String_Length - #i)
			add 1 to #i
			if #String_Length - #i = 0
				break
			end-if
		end-while

		if #Word_Position <> 0
			let $Last_Word = substr($Search_String, #Word_Position+1, #String_Length - #Word_Position)
		else
			let $Last_Word = ''
		end-if	

End-Procedure Get-Last-Word

!************************************************************************
! Get-Database-Name Procedure
!************************************************************************
Begin-Procedure Get-Database-Name(:$DatabaseName)

BEGIN-SELECT
DBNAME

	move &DBNAME	to $DatabaseName

FROM PSDBOWNER
END-SELECT

End-Procedure Get-Database-Name

!************************************************************************
! Procedure to lookup runtime values
!************************************************************************
begin-procedure Get-Value($paramName, :$paramValue)
	begin-select
value

        let $paramValue = &value

        from ps_um_sqrrun_param
        where
            oprid = $_prcs_oprid
            and run_cntl_id = $_prcs_run_cntl_id
            and lower(param_name) = lower($paramName)
       end-select
end-procedure
!************************************************************************
! End of Procedure to lookup runtime values
!************************************************************************